;Events.txt for "The War of the Ring" Scenario for
;Civilization 2 by Microprose Software, Inc.
;Alteration of this file can create problems in the scenario.

@BEGINEVENTS

@IF
SCENARIOLOADED
@THEN
DONTPLAYWONDERS
@ENDIF

@IF 
NEGOTIATION
talker=Anybody
talkertype=HumanOrComputer
listener=Anybody
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
TURN
turn=5
@THEN
PLAYWAVEFILE divcrash.wav
TEXT
^Sauron's chief lieutenants, the Nazgul,
 are unable to recover the One Ring. Their
 Dark Lord recalls them to Mordor.
ENDTEXT
MOVEUNIT
unit=Nazgul
owner=Mordor
maprect
101,13 165,13 165,53 101,53
moveto
168,66
numbertomove=All
@ENDIF

@IF
CITYTAKEN
city=Isengard
attacker=Anybody
defender=Armies of Saruman
@THEN
JUSTONCE
TEXT
^Isengard is taken!
^But Saruman escapes to the North where he is called
 Sharkey. He decries what he calls "the iron fist of
 Gondor and the Elves." And some listen......
ENDTEXT
@ENDIF

@IF
CITYTAKEN
city=Pelargir
attacker=Gondor
defender=Haradrim
@THEN
TEXT
^Pelargir falls to the forces of Gondor!
 Black Corsairs could help swing the tide
 against Sauron.
ENDTEXT
JUSTONCE
CREATEUNIT
owner=Gondor
unit=Black Corsair
veteran=Yes
homecity=Pelargir
locations
152,78
endlocations
@ENDIF

@IF
TURNINTERVAL
interval=6
@THEN
CREATEUNIT
owner=Mordor
unit=Orcs
veteran=Yes
homecity=None
locations
130,50 133,51
endlocations
@ENDIF

@IF
CITYTAKEN
city=Pelargir
attacker=Gondor
defender=Haradrim
@THEN
CREATEUNIT
owner=Gondor
unit=Black Corsair
veteran=Yes
homecity=Pelargir
locations
153,77
endlocations
@ENDIF

@IF
CITYTAKEN
city=Barad-dur
attacker=Anybody
defender=Mordor
@THEN
JUSTONCE
CREATEUNIT
owner=Gondor
unit=Swanship
veteran=Yes
homecity=None
locations
89,27 88,28 87,27 88,26
endlocations
TEXT
^The Ring and its Dark Lord have been destroyed and Barad-dur has been
 razed. Much work remains to be done. However, the Heir of Isildur
 reclaims his  throne and a New Age is heralded.
ENDTEXT
@ENDIF

@IF
TURN
turn=60
@THEN
TEXT
^Five years (60 turns)
 remain in this scenario.
ENDTEXT
@ENDIF

@IF
TURN
turn=108
@THEN
TEXT
^Only one year (12 turns)
 remains in this scenario.
ENDTEXT
@ENDIF

@ENDEVENTS

